Henkilöiden nimet

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT ?nimi
WHERE {
   ?henkilo a foaf:Person .
   ?henkilo skos:prefLabel ?nimi .
} LIMIT 20

Kirjojen teemat

PREFIX kauno: <http://www.yso.fi/onto/kaunokki#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?kirjannimi ?teemannimi
WHERE{
     ?kirja kauno:teema ?teema .
     ?kirja skos:prefLabel ?kirjannimi .
     ?teema skos:prefLabel ?teemannimi .
}     LIMIT 20

Kirsi Kunnaksen teosten määrä

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX kauno: <http://www.yso.fi/onto/kaunokki#>

SELECT (count(?teos) as ?teosmaara)
WHERE {
   ?henkilo a foaf:Person .
   ?henkilo skos:prefLabel "Kunnas, Kirsi" .
   ?teos kauno:tekija ?henkilo .
}

Sukkanauhakäärme-teoksen teemat suomeksi

PREFIX kauno: <http://www.yso.fi/onto/kaunokki#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT ?teemannimi

WHERE {
  ?kirja a kauno:romaani .
  ?kirja skos:prefLabel "Sukkanauhakäärme"@fi .
  ?kirja kauno:teema ?teema.
  ?teema skos:prefLabel ?teemannimi.
   FILTER (lang(?teemannimi) = 'fi')
} LIMIT 20

Kirjoja teemalla sota

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX kauno: <http://www.yso.fi/onto/kaunokki#>

SELECT  ?kirjannimi ?tekijannimi ("sota" as ?teemana)
WHERE {
   ?kirja a kauno:romaani .
   ?kirja skos:prefLabel ?kirjannimi .
   FILTER (lang(?kirjannimi) = "fi")
   ?kirja kauno:tekija ?tekija.
   ?tekija skos:prefLabel ?tekijannimi .
   ?kirja kauno:teema ?teema .
   ?teema skos:prefLabel "sota"@fi .
}
ORDER BY ASC(?kirjannimi) LIMIT 20

Romaanien teemoja

PREFIX kauno: <http://www.yso.fi/onto/kaunokki#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT DISTINCT ?teemannimi
where{
    ?romaani a kauno:romaani .
    ?romaani kauno:teema ?teema .
    ?teema skos:prefLabel ?teemannimi .
    FILTER(lang(?teemannimi) = 'fi')
} ORDER BY (?teemannimi) LIMIT 20

Suomalaisten romaanien pituus

PREFIX kauno: <http://www.yso.fi/onto/kaunokki#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX lingvoj: <http://www.lingvoj.org/lang/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
SELECT ?ilmvuosi (avg(xsd:int(?sivut)) AS ?sivujakeskimaarin) (count(*) as ?kirjoja)
WHERE {
  ?romaani rdf:type kauno:romaani .
  ?romaani kauno:alkukieli lingvoj:fi .
  ?romaani kauno:manifests_in ?painos .
  ?painos kauno:ilmestymisvuosi ?ilmvuosir .
  ?ilmvuosir skos:prefLabel ?ilmvuosi .
  ?painos kauno:sivuLkm ?sivut .
  FILTER(xsd:int(?sivut))
}
GROUP BY ?ilmvuosi
ORDER BY ASC(?ilmvuosi)